home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD005b.dsk / PIG.LATIN.bas < prev    next >
BASIC Source File  |  2003-06-12  |  3KB  |  49 lines
  1. 10  REM ** PIG LATIN **
  2. 20  REM ** AN ORIGINAL PROGRAM **
  3. 30  REM  ** CONTRIBUTED BY **
  4. 40  REM  **  SANDY SMITH   **
  5. 50  REM  ** FEBRUARY 1982  **
  6. 100  TEXT : HOME 
  7. 110  VTAB 5: HTAB 12: PRINT "** IGPAY ATINLAY **": VTAB 7: HTAB 16: PRINT "(PIG LATIN)"
  8. 120  VTAB 10: HTAB 8: PRINT "ANWAY ORIGINALWAY OGRAMPRAY": VTAB 12: HTAB 10: PRINT "(AN  ORIGINAL  PROGRAM)"
  9. 130  VTAB 15: HTAB 11: PRINT "YBAY ANDYSAY ITHSMAY": VTAB 17: HTAB 12: PRINT "(BY  SANDY  SMITH)"
  10. 140  FOR I = 1 TO 3000: NEXT I
  11. 150  HOME : PRINT : PRINT "I, THE MARVELOUS APPLE II WILL WRITE": PRINT "SENTENCES IN PIG LATIN FOR YOU!!"
  12. 160  PRINT : PRINT "FIRST YOU'LL NEED TO TELL ME HOW LONG": PRINT "YOUR SENTENCE WILL BE."
  13. 170  PRINT : PRINT "THEN YOU WILL TYPE THE WORDS AND I,": PRINT "BEFORE YOUR VERY EYES, WILL SHOW YOU"
  14. 180  PRINT "YOUR SENTENCE IN PIG LATIN.": PRINT : PRINT : PRINT "<> <> <> <> <> <> <> <> <> <> <> <> <>"
  15. 190  PRINT : HTAB 5: PRINT "HOW MANY WORDS WILL BE IN YOUR": HTAB 5: INPUT "SENTENCE? ";N$:N =  VAL(N$): IF N = 0  THEN 190
  16. 200  PRINT : HTAB 5: PRINT "TYPE ONE WORD AT A TIME AND": HTAB 5: PRINT "THEN PRESS THE 'RETURN' KEY.": PRINT 
  17. 210  DIM X$(N)
  18. 220  FOR I = 1 TO N: HTAB 5: PRINT "WORD ";I;: INPUT ": ";X$(I): NEXT I
  19. 230  PRINT : HTAB 5: PRINT "WHAT PUNCTUATION DO YOU WANT": HTAB 5: INPUT "AT THE END? ";P$: PRINT : PRINT 
  20. 240  IF P$ < >"."  AND P$ < >"!"  AND P$ < >"?"  THEN 230
  21. 250  FOR I = 1 TO N
  22. 260  REM IS THE FIRST LETTER OF  THIS WORD A VOWEL?
  23. 270  IF  LEFT$(X$(I),1) = "A"  OR  LEFT$(X$(I),1) = "E"  OR  LEFT$(X$(I),1) = "I"  OR  LEFT$(X$(I),1) = "O"  OR  LEFT$(X$(I),1) = "U"  THEN 510
  24. 280  REM IS THE SECOND LETTER OF THIS WORD A VOWEL?
  25. 290  IF  MID$ (X$(I),2,1) = "A"  OR  MID$ (X$(I),2,1) = "E"  OR  MID$ (X$(I),2,1) = "I"  OR  MID$ (X$(I),2,1) = "O"  OR  MID$ (X$(I),2,1) = "U"  OR  MID$ (X$(I),2,1) = "Y"  THEN 530
  26. 300  REM IS THE THIRD LETTER OF  THIS WORD A VOWEL?
  27. 310  IF  MID$ (X$(I),3,1) = "A"  OR  MID$ (X$(I),3,1) = "E"  OR  MID$ (X$(I),3,1) = "I"  OR  MID$ (X$(I),3,1) = "O"  OR  MID$ (X$(I),3,1) = "U"  OR  MID$ (X$(I),3,1) = "Y"  THEN 550
  28. 320  IF  MID$ (X$(I),4,1) = "A"  OR  MID$ (X$(I),4,1) = "E"  OR  MID$ (X$(I),4,1) = "I"  OR  MID$ (X$(I),4,1) = "O"  OR  MID$ (X$(I),4,1) = "U"  OR  MID$ (X$(I),4,1) = "Y"  THEN 570
  29. 330  REM WORD MUST BE TYPED WRONG
  30. 340  GOTO 590
  31. 350  NEXT I
  32. 360  REM  CHECK CURSOR POSITION, MOVE IT BACK ONE SPACE AND  PRINT PUNCTUATION
  33. 370 CH =  PEEK(36): POKE 36,CH -1: PRINT P$
  34. 380  PRINT : PRINT "THERE! WASN'T THAT CLEVER OF ME!"
  35. 390  PRINT : INPUT "DO YOU WANT TO DO ANOTHER SENTENCE? ";A$
  36. 400  IF  LEFT$(A$,1) = "Y"  THEN  HOME : RUN 190
  37. 410  IF  LEFT$(A$,1) < >"N"  THEN 390
  38. 420  PRINT : PRINT "EESAY OUYAY ATERLAY!!"
  39. 430  END 
  40. 500  REM  THE WORD STARTS WITH A VOWEL, ADD 'WAY' TO THE END OF THE WORD
  41. 510  PRINT X$(I) +"WAY ";: GOTO 350
  42. 520  REM THE WORD STARTS WITH A SINGLE CONSONANT, MOVE THE  CONSONANT TO THE END OF THE WORD AND ADD 'AY'
  43. 530  PRINT  MID$ (X$(I),2) + LEFT$(X$(I),1) +"AY ";: GOTO 350
  44. 540  REM THE WORD STARTS WITH 2 CONSONANTS, MOVE THEM TO THEEND OF THE WORD AND ADD 'AY'
  45. 550  PRINT  MID$ (X$(I),3) + LEFT$(X$(I),2) +"AY ";: GOTO 350
  46. 560  REM THE WORD STARTS WITH 3 CONSONANTS, MOVE THEM TO THEEND OF THE WORD AND ADD 'AY'
  47. 570  PRINT  MID$ (X$(I),4) + LEFT$(X$(I),3) +"AY ";: GOTO 350
  48. 580  REM THE WORD TYPED STARTS  WITH MORE THAN 3 CONSONANTS
  49. 590  PRINT : PRINT : PRINT  CHR$(7);"YOU MUST BE TRYING TO TRICK ME!": PRINT : PRINT "LET'S START ALL OVER!": FOR I = 1 TO 500: NEXT I: RUN 190